Import relationships using a csv file

[11li]

Hi, I'm new to neo4j and Cypher language.
I have created 2 kinds of nodes using cypher:

load csv with headers from 'file:///trackCheckContent.csv' as line
create(:TrackCheckContent{risk:line.risk,risk_id:line.risk_id,info_source:line.source,url:line.URL,checkFrequency:line.checkFrequency})

load csv with headers from 'file:///checkAppliance.csv' as line
create(:checkAppliance{appliance:line.check_appliance,appliance_id:line.appliance_id})

Now I want to create relationship between these 2 kinds of node.
I have a csv file be like:

then I use cypher:

LOAD CSV WITH HEADERS FROM "file:///risk_appliance.csv" AS row 
match (from:TrackCheckContent{id:row.risk_id})
match (to:checkAppliance {id:row.appliance_id}) 
merge (from)-[r:use]->(to)

It turns out to be (no changes, no records)

And if I try this:

LOAD CSV WITH HEADERS FROM "file:///risk_appliance.csv" AS row 
match (from:TrackCheckContent{id:row.risk_id}),(to:checkAppliance {id:row.appliance_id}) 
merge (from)-[r:use]->(to)

I will get This query builds a cartesian product between disconnected patterns.

I just want to create relationships between these 2 kinds of node. plz help

[Cobra]

Hello @11li and welcome to the Neo4j community

Can you share the CSV files to create nodes and relationships?

Regards,
Cobra

[11li]

Hi!
Followings are part of my files.
csv can't upload.
trackCheckContent.csv

checkAppliance.csv

Thank you!

Regards,
Yiyi

[Cobra]

You can upload files here but you must replace the extension of the files by .txt.

[11li]

ok! thanks!
checkAppliance.txt (417 Bytes)
risk_appliance.txt (860 Bytes)
trackCheckContent.txt (10.4 KB)

[Cobra]

Thank you, I'm gonna try to find your issue now

[Cobra]

First, you must create UNIQUE CONSTRAINTS:

CREATE CONSTRAINT constraint_track_check_content IF NOT EXISTS FOR (n:TrackCheckContent) REQUIRE n.risk_id IS UNIQUE;
CREATE CONSTRAINT constraint_check_appliance IF NOT EXISTS FOR (n:CheckAppliance) REQUIRE n.appliance_id IS UNIQUE;

Then you load nodes:

LOAD CSV WITH HEADERS FROm 'file:///TrackCheckContent.csv' AS line
MERGE (n:TrackCheckContent {risk_id: line.risk_id}) SET n += line

LOAD CSV WITH HEADERS FROm 'file:///CheckAppliance.csv' AS line
MERGE (n:CheckAppliance {appliance_id: line.appliance_id}) SET n += line

Finally, you load relationships:

LOAD CSV WITH HEADERS FROm 'file:///RiskAppliance.csv' AS line
MATCH (a:TrackCheckContent {risk_id: line.risk_id})
MATCH (b:CheckAppliance {appliance_id: line.appliance_id})
MERGE (a)-[:USE]->(b)

Everything worked on my end and I used the latest version of Neo4j (4.4.3).

[11li]

UNIQUE CONSTRAINTS got this error.

I used Neo4j Browser version: 4.2.2

Neo4j Server version: 4.2.3 (community)

[Cobra · Accepted solution]

Try that:

CREATE CONSTRAINT constraint_track_check_content IF NOT EXISTS ON (n:TrackCheckContent) ASSERT n.risk_id IS UNIQUE;
CREATE CONSTRAINT constraint_check_appliance IF NOT EXISTS ON (n:CheckAppliance) ASSERT n.appliance_id IS UNIQUE;

[11li]

It worked!!! Thank you very much !

I still got one question that why can't I change the caption of this kind of node.

[Cobra]

No problem, what do you mean by the caption?

[11li]

like this

[Cobra]

Oh, yes, you can, there is an arrow on the right on the same line, just click on it and you will see the properties.

[11li]

oh!! I see!!!
thank you very much !!!!!

[11li]

Sorry to bother you again😅
Could you please tell me how can I delete all the data?

After I executed "match (n) detach delete n"
Node labels and property keys are still there.

[11li]

I checked your other answers and try drop constraint

It worked!
but the property keys are still there.

[Cobra]

If you want to clean everything:

CREATE OR REPLACE DATABASE neo4j

[11li]

Cobra:

CREATE OR REPLACE DATABASE neo4j

Sorry for the late reply. But it didn't work

[11li]

Cobra:

CREATE OR REPLACE DATABASE neo4j

Version:	4.2.3
Edition:	Community
Name:	neo4j
Databases:	:dbs
Information:	:sysinfo
Query List:	:queries

still can't...

[Cobra]

Ah, you are on Community version, that's why it's not working, you can check the documentation here.
For Community version, you will have to drop the folder of the database then recreate a database.

[11li]

Thank you!
So I can't just write a line to delete all peoperty keys, right?

[Cobra]

Yeah that's right, there is no alternative option right now:)

[11li]

Documentation only support enterprise edition...

and I don't know which part of the folder can be deleted...

Is there a documentation support Community version?

[Cobra]

Delete the neo4j folder in the databases folder and it should be good but you will have to recreate a database after.

[11li]

I delete the noe4j database...and I couldn't create it back...
How to create a database in community version?

[Cobra]

Did you shutdown the server before to delete the folder and did you restart it after?

You should open another topic for this problem.

[11li]

Thank you!
Yes, I did shutdown the server before I delete the neo4j folder and restart it.
But it turns out to be the picture I sent. So I delete the whole folder and download a new community version
Now it's ok.
I will open another topic when I have to create a database after.