Using list comprehension for get both node and edge property together

[madiganz]

I'm trying to figure out how to run a subquery and combine an edge property with the node property, but I can't figure out how. What I would like to do is something like:

MATCH (person:Person)
RETURN person {.id, .name, Homes: [(person)-[r:OWNS]-(p:Property) | <not sure what to do here>{p.address, r.purchaseDate}]}

I have tried any combination of p and r for the list comprehension and nothing seems to work. Is this possible, or do I need to return these values separately?

[andrew_bowman · Accepted solution]

That's interesting, the literal map should have been valid. Which version of Neo4j were you using?

As a workaround, you can use map projection again to get around that syntax error:

MATCH (person:Person)
RETURN person {.id, .name, Homes: [(person)-[r:OWNS]-(p:Property) | p {.address, purchaseDate:r.purchaseDate}]}

[madiganz]

Ah thank you! It also works if I just use

{address:p.address, purchaseDate:r.purchaseDate}

So it's something to do with needing to name the relationship property

[andrew_bowman]

Ah, there you go, I overlooked that you were missing key:value syntax. That's needed when working with map literals.

[glilienfield]

Try this:

match(p:Person{id:100})
match(p)-[r:OWNS]->(h:Home)
with p, collect({address: h.address, purchaseDate: r.purchaseDate}) as homes
return p{.id, .name, homes: homes}

[madiganz]

Are there any performance implications to using this method of a second match and collect vs the subquery and projection?

[glilienfield]

I just like the readability, but you can merge the two matches:

match(p:Person{id:100})-[r:OWNS]->(h:Home)
with p, collect(h{.address, purchaseDate: r.purchaseDate}) as homes
return p{.id, .name, homes: homes}

[madiganz]

Are you saying that the performance is equivalent?

[glilienfield]

That I do not know. Your query is performing two queries, one in the initial match for the person, and then a second in the pattern match for the home when creating your collection of homes.

[madiganz]

Well thank you to you both. Both are good solutions!